cocoaforge

Code: Select all

-- This script will count the new mail found in all your mailboxes, display a Fastscripts notification, and then open all the mailboxes that have new mail.

-- Eudora keeps your mailboxes in a folder called "Mail Folder" found in¬("Your_HD:Users:Your_Username:Documents:Eudora Folder:)

-- To get the proper address in the following statement, run another script with the statement set myChoice to (choose folder), navigate to your Eudora Mail folder and copy the result into the "set mF..." statement below.

set mF to alias "ACB-HD:Users:bellac:Documents:Eudora Folder:Mail Folder:"

tell application "Finder" to set boxes to mF's entire contents
set mbCount to count of boxes
set BoxesWithMail to {}
set CountInBoxes to {}
set Apl to ((ASCII character 240) & space & space)

repeat with j from 1 to mbCount
	set mbName to last word of (item j of boxes as text)
	set newMail to checkNewMail(mbName)
	if newMail > 0 then
		set end of BoxesWithMail to mbName
		set end of CountInBoxes to newMail
	end if
end repeat

if length of BoxesWithMail = 0 then
	tell application "GrowlHelperApp" to notify with name "EudoraCheck" title "Eudora says:" description return & Apl & "No mail"
else
	set mailNotice to TellMe(BoxesWithMail, CountInBoxes)
	tell application "GrowlHelperApp"
		notify with name "EudoraCheckG" title "You Have Mail" description (return & mailNotice) application name "EudoraCheckG"
	end tell
	
	tell application "Eudora"
		repeat with k from 1 to count of BoxesWithMail
			if item k of BoxesWithMail = "Inbox" then
				open mailbox "In"
			else
				open mailbox (item k of BoxesWithMail)
			end if
		end repeat
	end tell
end if


on checkNewMail(mail_box)
	tell application "Eudora"
		if ((name of mailbox mail_box = "Trash") or (name of mailbox mail_box = "Junk")) then
			set MailWaiting to 0
		else
			set MailWaiting to recent unread in mailbox mail_box
		end if
		return MailWaiting
	end tell
end checkNewMail

on TellMe(boxList, MailCount)
	set msg to ""
	set boxCount to count of boxList
	repeat with n from 1 to boxCount
		if item n of boxList = "In" then set item n of boxList to "Inbox"
		set msg to msg & my Apl & (item (n) of MailCount as text) & " waiting in " & (item n of boxList) & return
	end repeat
	return msg
end TellMe